{ stdenv, fetchurl, pkgconfig, attr, acl, zlib, libuuid, e2fsprogs, lzo
, asciidoc, xmlto, docbook_xml_dtd_45, docbook_xsl, libxslt, zstd, python3
, buildPackages
}:

stdenv.mkDerivation rec {
  pname = "btrfs-progs";
  version = "5.4";

  src = fetchurl {
    url = "mirror://kernel/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v${version}.tar.xz";
    sha256 = "1ykhasv0jc3qi3xrm5841mzkmlbkjw6rm70gl4aww90jj6ak55qg";
  };

  nativeBuildInputs = [
    pkgconfig asciidoc xmlto docbook_xml_dtd_45 docbook_xsl libxslt
    buildPackages.python3 buildPackages.python3.pkgs.setuptools
  ];

  buildInputs = [ attr acl zlib libuuid e2fsprogs lzo zstd python3 ];

  # for python cross-compiling
  _PYTHON_HOST_PLATFORM = stdenv.hostPlatform.config;
  # The i686 case is a quick hack; I don't know what's wrong.
  postConfigure = stdenv.lib.optionalString (!stdenv.isi686) ''
    export LDSHARED="$LD -shared"
  '';

  # gcc bug with -O1 on ARM with gcc 4.8
  # This should be fine on all platforms so apply universally
  postPatch = "sed -i s/-O1/-O2/ configure";

  preConfigure = stdenv.lib.optionalString (stdenv.buildPlatform != stdenv.hostPlatform) ''
    cat > python-for-build <<'EOF'
#!${stdenv.shell}
export PYTHONNOUSERSITE=1
export PYTHONPATH=${python3}/lib/python3.7
export _PYTHON_SYSCONFIGDATA_NAME=_sysconfigdata_m_linux_arm-linux-gnueabi
exec ${buildPackages.python3}/bin/python3 "$@"
EOF
    chmod +x python-for-build
    export PYTHON=$PWD/python-for-build
  '';

  makeFlags = stdenv.lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
    "EXTRA_PYTHON_CFLAGS=-I${python3}/include/python3.7m"
    "EXTRA_PYTHON_LDFLAGS=-L${python3}/lib -lpython3.7m"
  ];

  postInstall = ''
    install -v -m 444 -D btrfs-completion $out/etc/bash_completion.d/btrfs
  '';

  configureFlags = stdenv.lib.optional stdenv.hostPlatform.isMusl "--disable-backtrace";

  meta = with stdenv.lib; {
    description = "Utilities for the btrfs filesystem";
    homepage = https://btrfs.wiki.kernel.org/;
    license = licenses.gpl2;
    maintainers = with maintainers; [ raskin ];
    platforms = platforms.linux;
  };
}